在 Excel 中，Frequency函數用于統計數值在指定區域內的出現頻率，并以垂直數組的形式返回統計結果。Frequency函數不是統計某個數值在指定區間的出現頻率而是統計指定區間有多少個數字。

Frequency函數比較典型的應用是統計不同分數段和不同年齡段的人數，該應用比較簡單，不需要與其它函數組合。但若要實現橫向統計或連續出現次數統計，則需要與 Transpose、Max、Row 函數組合，例如 Transpose + Frequency + Row 可實現橫向統計。

一、Excel Frequency函數的語法

1、表達式：FREQUENCY(Data_Array, Bins_Array)

中文表達式：頻率計數(數值數組或對數值單元格的引用, 區間數組)

2、說明：

A、如果 Data_Array 中沒有數值，Frequency函數只返回一個零數組。另外，Frequency函數忽略空白和文本。

B、如果 Bins_Array 中無數值，Frequency函數將返回 Data_Array 中的元素個數。

C、Frequency函數返回的數組元素比 Bins_Array 的元素多一個，多出的元素為大于最高間隔數值的計數，具體見下文的實例。

D、如果要求Frequency函數返回數組，必須以數組形式輸入，即輸入完公式后要按 Ctrl + Shift + 回車。例如要把不同區間的統計結果填充到相鄰單元格，則選中相鄰單元格后，就需要按 Ctrl + Shift + 回車，具體操作見下文的實例。

二、Excel Frequency函數的使用方法及實例

（一）Frequency函數忽略空白和文本及返回的數組元素比 Bins_Array 的元素多一個的實例

1、雙擊 C2 單元格，把公式 =INDEX(FREQUENCY(A2:A6,B2:B3),2) 復制到 C2，按 Ctrl + Shift + 回車（Excel 2016 也可以直接按回車），返回 2；按住 Alt，依次按 M 和 V，打開“公式求值”窗口，按回車求值，則 Frequency函數返回數組{1;2;0}；操作過程步驟，如圖1所示：

圖1

2、公式 =INDEX(FREQUENCY(A2:A6,B2:B3),2) 說明：

A、A2:A6 為Frequency函數的引用單元格區域，該區域有空單元格和文本，但它們被忽略；B2:B3 為區間數組，可分為三個區間，第一個為小于等于 5，第二個為大于 5 且小于等于 10，第三個為大于 10。

B、執行時，第一次在 A2:A6 中統計第一個區間（即小于等于 5）的數值出現頻率，該區間只有一個 5，它的出現頻率為 1，因此返回 1；第二次在 A2:A6 中統計第二個區間（即大于 5 且小于等于 10）的數值出現頻率，該區間有 8 和 10 兩個數，它們的出現頻率各為 1，因此返回 2（返回的結果是該區間各數出現頻率之和）；第三次在 A2:A6 中統計第三個區間（即大于 10）的數值出現頻率，由于無大于 10 的數值，因此返回 0。

C、則 FREQUENCY(A2:A6,B2:B3) 最后返回 {1;2;0}，Bins_Array 參數 B2:B3 只有兩個元素，而返回數組 {1;2;0} 有三個元素，最后一個元素 0 是統計第三個區間（即大于 10）的數值出現頻率。

D、則公式變為 =INDEX({1;2;0},2)，最后用Index函數返回數組中第二行第一列的數值，即返回 2。這里之所以要用Index函數，是因為僅用Frequency函數若不選中相鄰單元格無法返回數組。

（二）Frequency函數返回一個零數組的實例

1、雙擊 A8 單元格，把公式 =FREQUENCY(A2:A7,A2:A7) 復制到 A8，按回車，返回 0；操作過程步驟，如圖2所示：

圖2

2、公式 =FREQUENCY(A2:A7,A2:A7) 說明：

公式的兩個參數都為 A2:A7，由于該區域全為文本，而Frequency函數忽略文本，因此結果返回 0。

（三）有重復數字與把不同區間的統計結果填充到相鄰單元格的實例

1、框選 C2:C3，輸入等號 =，然后按 Ctrl + V 把公式 FREQUENCY(A2:A7,B2:B3) 粘貼到 = 后，按 Ctrl + Shift + 回車，則選中單元格都填上相應的統計結果；操作過程步驟，如圖3所示：

圖3

2、公式說明：

A、C2 中的結果 3 是 A2:A7 中小于等于 5 的數值個數，該區間的共有兩個 5 和一個 3，加起來恰好是 3 個數值，由此可知Frequency函數統計的是區間的數值個數，而不是某個數字的個數。

B、C3 中的結果 8 是 A2:A7 中大于 5 且小于等于 10 的數值個數，該區間有 6、8 和 10，也是 3 個數值。

C、由于同時框選 C2:C3 且同時填充公式，它們已經組成一個組，不能單獨修改或刪除，只有同時選中它們才能修改或刪除。

三、Excel Frequency函數的應用實例

（一）統計不同分數段的人數實例

1、假如要統計不及格、60-69、70-79、80-89、90-99 和 100 分的學生人數�？蜻x D2:D7，輸入等號 =，把公式 FREQUENCY(B2:B28,C2:C6-1) 復制到 = 后，按 Ctrl + Shift + 回車，統計出不同分數段的學生人數；操作過程步驟，如圖4所示：

圖4

2、公式 =FREQUENCY(B2:B28,C2:C6-1) 說明：

A、由于 C2:C6 中都是 60、70，而要統計不及格、60-69 這樣分數段的人數，因此要用 C2:C6-1，其實是用 C2:C6 中的每個數值減 1。如果不減 1，可直接在 C2:C6 中填 59、69、79、89、99。

B、D2 中的統計結果 0 是不及格的人數，D3 中的 1 是 60-69 分數段的人數，D4 中的 8 是 70-79 分數段的人數，D5 中的 9 是 80-89 分數段的人數，D6 中的 9 是 90-99 分數段的人數，D7 中的 0 是 100 分的人數。

提示：如果不專門統計 100 分的人數，而是把 100 分歸到 90 分以上分數段，可以把 C6 中的 100 改為 101。另外，統計不同年齡段的人數也是一樣的方法。

（二）Transpose + Frequency + Row 組合實現橫向統計實例

1、假如要統計 0 到 7 每個數字出現的頻率并把統計結果橫向顯示�？蜻x A10:H10，輸入等號 =，把公式 TRANSPOSE(FREQUENCY(A1:F7,ROW(1:8)-1)) 復制到 = 后，按 Ctrl + Shift + 回車，則統計出 A1:F7 中 1 到 7 各數字的出現頻率；操作過程步驟，如圖5所示：

圖5

2、公式 =TRANSPOSE(FREQUENCY(A1:F7,ROW(1:8)-1)) 說明：

A、ROW(1:8)-1 用于以數組形式返回 0 到 7 的數字，ROW(1:8) 以數組形式返回 1 到 8 的數字，然后再用每個數字減 1，最后返回 0 到 7 的數字。

B、Transpose函數把Frequency函數返回結果由列轉為行，如果不用Transpose函數，盡管同時選中 A10:H10，但只能統計出 0 的頻率。

（三）Max + Frequency + Row 組合統計連續次數最多的實例

1、假如要統計連續增長最多的月份數。雙擊 C2 單元格，把公式 =MAX(FREQUENCY(ROW(1:12),(B2:B13<>1)*ROW(1:12)))-1 復制到 C2，按回車，返回 4；操作過程步驟，如圖6所示：

圖6

2、公式 =MAX(FREQUENCY(ROW(1:12),(B2:B13<>1)*ROW(1:12)))-1 說明：

A、ROW(1:12) 以數組形式返回 1 到 12 的數字，即 {1;2;3;4;5;6;7;8;9;10;11;12}。

B、B2:B13 以數組形式返回 B2:B13 中的所有數字，即 {1;1;0;1;1;1;1;0;0;1;1;1}；則 B2:B13<>1 變為 {1;1;0;1;1;1;1;0;0;1;1;1}<>1，接著從數組中取出每個元素與 1 比較，如果不等于 1 返回 TRUE，否則返回 FALSE，則最后返回 {FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;FALSE;TRUE;TRUE;FALSE;FALSE;FALSE}。

C、則 (B2:B13<>1)*ROW(1:12) 變為 {FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;FALSE;TRUE;TRUE;FALSE;FALSE;FALSE}*{1;2;3;4;5;6;7;8;9;10;11;12}，接著把兩個數組中對應的元素相乘（相乘時，TRUE 轉為 1、FALSE 轉為 0），則最后返回 {0;0;3;0;0;0;0;8;9;0;0;0}，這樣就求得了 Frequency 的區間，每個區間恰好以 B2:B13 中為 0 的數值為分割點。

D、則公式變為 =MAX(FREQUENCY({1;2;3;4;5;6;7;8;9;10;11;12},{0;0;3;0;0;0;0;8;9;0;0;0}))-1，進一步計算，在第一個數組中統計大于 0 且小于等于 3 的數字個數、大于 3 且小于等于 8 的數字個數，大于 8 且小于等于 9 的數字個數和大于 9 的數字個數，結果為 {0;0;3;0;0;0;0;5;1;0;0;0;3}。

E、則公式變為 =MAX({0;0;3;0;0;0;0;5;1;0;0;0;3})-1，接著用 Max 對數組中的元素求最大值，結果為 5，5-1 等于 4。之所以要減 1，是因為用Frequency函數統計每個區間的數字個數時，包含了 B2:B13 中為 0 的數字，例如統計大于等于 0 且小于 3 的這個區間就包含了 3，而 3 是 B4 中的 0 返回的值。

另外，用 Sum + If + Frequency 組合還可以實現中國式排名，具體請參考《Rank函數怎么用的11個實例，含與Rank.EQ和Rank.AVG的區別、并順自動排序和排名次及分段排序》一文。